CoddyRunParcours Le budget de poche Étape 1
Noter ses dépenses
Saisir des montants jusqu'à ce que l'utilisateur tape 0, puis afficher le total, le nombre de dépenses et la dépense moyenne.
Notions :tableautant quesommemoyenne
Chaque dépense est un montant, rangé dans un tableau. On en saisit autant qu'on veut ; le 0 sert de signal d'arrêt.
montant vaut -1
tant que montant <> 0
demande "Montant de la dépense en € (0 pour terminer) : " dans montant
si montant > 0 alors
depenses ajoute montant
fin si
fin tant queOn met montant à -1 avant la boucle, pour être sûr d'y entrer. Les montants négatifs sont refusés avec un message.
Les calculs
CoddyRun calcule directement sur un tableau :
somme(depenses): le total ;moyenne(depenses): la dépense moyenne ;longueur(depenses): le nombre de dépenses.
Les centimes se tapent avec un point : 3.50. On arrondit les résultats à deux décimales avec decimal(…, 2).
Si aucune dépense n'a été saisie, moyenne n'aurait rien à calculer : on vérifie d'abord, et on arrête proprement avec terminer.
Ouvrez CoddyRun et partez d'un programme vide : tout commence ici.
Il te faut le logiciel pour faire cette étape. Il est gratuit : crée ton compte pour le télécharger, puis reviens ici, ta place t'attend.
Créer mon compte et téléchargerIndice 1
Déclarez depenses est un tableau et montant, total est un nombre.
Indice 2
Le refus des négatifs : si montant < 0 alors … sinon si montant > 0 alors ….
Indice 3
Testez avec 3.50, 12 et 8.25 : le total doit faire 23,75 €.
Voir la solution complète
Essayez d'abord par vous-même : c'est en cherchant qu'on apprend. La solution sert à vérifier ou à se débloquer.
@ Les déclarations
depenses est un tableau
montant, total est un nombre
@ La saisie
html("<h2>Le budget de poche</h2>")
montant vaut -1
tant que montant <> 0
demande "Montant de la dépense en € (0 pour terminer) : " dans montant
si montant < 0 alors
affiche "Un montant ne peut pas être négatif."
sinon si montant > 0 alors
depenses ajoute montant
fin si
fin tant que
si longueur(depenses) = 0 alors
affiche "Aucune dépense saisie."
terminer
fin si
@ Les calculs
total vaut somme(depenses)
affiche "Total : " + convertir_texte(decimal(total, 2)) + " €"
affiche "Nombre de dépenses : " + convertir_texte(longueur(depenses))
affiche "Dépense moyenne : " + convertir_texte(decimal(moyenne(depenses), 2)) + " €"